Arduino

технологии

Модуль часов реального времени DS1307

Модуль используется для создания часов а также устройств, для работы которых требуется знание текущего времени.

Внешний вид модуля:

Для работы модуля требуется батарейка CR2032. Такие батарейки или аккумуляторы стоят обычно в материнских платах компьютеров.

С Arduino модуль работает по протоколу I2C. Для его использования требуется подключить контакты GND и VCC к контактам земли и 5V, а контакты SCL и SDA - к соответствующим контактам платы arduino. В зависимости от того, какую плату вы используете, контакты будут разные:

Плата Пин SDA Пин SCL
Uno, Nano A4 A5
Mega2560 20 21
Leonardo 2 3
Due 20, SDA1 21, SCL1

Подключаем модуль к Arduino Uno

Схема подключения модуля реального времени DS1307 к Arduino Uno

После того, как мы вставили батарейку и подключили модуль, нужно установить время. Достаточно сделать это 1 раз и далее модуль будет "тикать", пока не сядет заряд батарейки. Загрузите и запустите следующий скетч (не забыв поставить все необходимые библиотеки):

#include <Wire.h>                           
#include <TimeLib.h>
#include <DS1307RTC.h>

const char *monthName[12] = {
  "Jan", "Feb", "Mar", "Apr", "May", "Jun",
  "Jul", "Aug", "Sep", "Oct", "Nov", "Dec"
};

tmElements_t tm;

void setup() 
{
  bool parse = false;
  bool config = false;

  if (getDate(__DATE__) && getTime(__TIME__)) {
    parse = true;
    if (RTC.write(tm)) {
      config = true;
    }
  }

  Serial.begin(9600);
  while (!Serial);
  delay(200);
  if (parse && config) {
    Serial.print("DS1307 configured Time=");
    Serial.print(__TIME__);
    Serial.print(", Date=");
    Serial.println(__DATE__);
  } else if (parse) {
    Serial.println("DS1307 Communication Error :-{");
    Serial.println("Please check your circuitry");
  } else {
    Serial.print("Could not parse info from the compiler, Time=\"");
    Serial.print(__TIME__);
    Serial.print("\", Date=\"");
    Serial.print(__DATE__);
    Serial.println("\"");
  }
}

void loop() 
{
}

bool getTime(const char *str)
{
  int Hour, Min, Sec;

  if (sscanf(str, "%d:%d:%d", &Hour, &Min, &Sec) != 3) {
    return false;
  }
  tm.Hour = Hour;
  tm.Minute = Min;
  tm.Second = Sec;
  return true;
}

bool getDate(const char *str)
{
  char Month[12];
  int Day, Year;
  uint8_t monthIndex;

  if (sscanf(str, "%s %d %d", Month, &Day, &Year) != 3) {
    return false;
  }
  for (monthIndex = 0; monthIndex < 12; monthIndex++) {
    if (strcmp(Month, monthName[monthIndex]) == 0) {
      break;
    }
  }
  if (monthIndex >= 12) {
    return false;
  }
  tm.Day = Day;
  tm.Month = monthIndex + 1;
  tm.Year = CalendarYrToTm(Year);
  return true;
}

Откройте мониторинг порта и если вы увидели сообщение "DS1307 configured Time=...", значит все получилось и в модуль было прописано текущее время, в качестве которого было взято время компиляции.

Теперь можно запустить второй скетч, который запросит текущее время у модуля и выведет его в консоль:

#include <Wire.h>                           
#include <TimeLib.h>
#include <DS1307RTC.h>

void setup() 
{
  Serial.begin(9600);
  while (!Serial);
  delay(200);
}

void loop() 
{
  tmElements_t tm;                          

  if (RTC.read(tm)) {
    Serial.print("Ok, Time = ");
    print2digits(tm.Hour);
    Serial.write(':');
    print2digits(tm.Minute);
    Serial.write(':');
    print2digits(tm.Second);
    Serial.print(", Date (D/M/Y) = ");
    Serial.print(tm.Day);
    Serial.write('/');
    Serial.print(tm.Month);
    Serial.write('/');
    Serial.print(tmYearToCalendar(tm.Year));
    Serial.println();
  } else {
    if (RTC.chipPresent()) {
      Serial.println("The DS1307 is stopped.  Please run the SetTime");
      Serial.println("example to initialize the time and begin running.");
      Serial.println();
    } else {
      Serial.println("DS1307 read error!  Please check the circuitry.");
      Serial.println();
    }
    delay(9000);
  }
  delay(1000);
}

void print2digits(int number) {
  if (number >= 0 && number < 10) {
    Serial.write('0');
  }
  Serial.print(number);
}

Видим строчку "Ok, Time = 18:32:49, Date (D/M/Y) = 13/2/2019" - все получилось. Ну а далее, например, добавив 7-сегментный дисплей, мы можем собрать часы.

Купить модуль часов можно здесь, здесь или здесь, но учтите, что шину контактов припаять придется самому.

Для ленивых есть шилд для Arduino uno с модулем часов, но он не такой миниатюрный.

Батарейки формата CR2032 можно купить в и магазине, но проще заказать сразу 10 или 20 штук.